* QUESITO: la perdita del partner influenza la qualità della vita?
 ******************************************************************
 * ora il nostro trattamento è un evento che accade tra le wave
 * ossia la perdita del partner
 *****************************************************************
 * notate che non vivere più con il partner può essere dovuto 
 * sia alla morte che al divorzio/ separazione
 *****************************************************************
 * SAMPLE SELECTION: POPULATION AT RISK
 *****************************************************************
 drop if wave<7
 gen sample=1 if partnerinhh==1 & wave==7
 sort mergeid wave
 replace sample=1 if sample[_n-1]==1 & sample==. & mergeid==mergeid[_n-1]
 tab sample wave
 recode sample(1=.) if wave==7 & mergeid!=mergeid[_n+1]
 tab sample wave
 
 ***************************************************************
 * variabile indipendente
sort mergeid wave
 gen plost=1 if partnerinhh==3 &  partnerinhh[_n-1]==1 & mergeid==mergeid[_n-1]
 recode plost(.=0) if sample==1
 tab plost wave if sample==1 & female==1
 
 *variabile dipendente
 mean casp if wave==8 & female==1 & eurod>-1, over(plost)
 
 *************************************************************************************
 * possibili effetti confondenti: istruzione, paese età, e salute del partner
 recode isced1997_r (0/2=1 "low") (3 4=2 "med") (5 6=3 "high"),gen(educ)
recode educ(95 97 -15 -12=.)

recode chronic (min/-1=.),gen(chronic2)

*ci concentriamo sulle donne con partner uomini
gen chronic_m=chronic2 if female==0
bys coupleid: egen chronic_p=min(chronic_m)if wave==7

tab sample wave if female==1
tab sample wave if female==1 & chronic_p!=. 
*introduciamo dei missing: in questo esempio non ci preoccupiamo dei missing

*definiamo i due gruppi
sort mergeid wave
gen treat=1 if plost==1 | (mergeid==mergeid[_n+1] & plost[_n+1]==1) 
recode treat(.=0)

tab treat wave if sample==1 & female==1 & coupleid!=""
tab treat wave if sample==1 & female==1 & chronic_p!=.


**************************************************************************************
*fattori confondenti
hist age_p  if sample==1 & female==1 & chronic_p!=., by(treat)
hist chronic_p  if sample==1 & female==1 & chronic_p!=., by(treat) dis
tab educ treat if sample==1 & female==1 & chronic_p!=.,

*************************************************************************************
* selezioniamo il campione
 drop if sample!=1 | casp<0 | female==0
 
 *il nostro outcome dovrebbe essere post-treatment
 sort mergeid wave
 gen casp1=casp[_n+1] if mergeid==mergeid[_n+1]
 
 tab casp1 wave
*************************************************************************************
* NN propensity score senza replacement
help psmatch2 

psmatch2 treat c.age_p##c.age_p i.country i.educ chronic_p if wave==7, noreplacement  ///
out(casp) n(1) common caliper(.01) 
pstest c.age_p##c.age_p i.country i.educ chronic_p, both
pstest age_p, both density
pstest chronic_p, both density

psmatch2 treat c.age_p##c.age_p i.country i.educ chronic_p if wave==7, noreplacement  ///
out(casp1) n(1) common caliper(.01) 

***************************************************************************************
* Radius
psmatch2 treat c.age_p##c.age_p i.country i.educ chronic_p if wave==7,  ///
out(casp1) radius common caliper(.01) 

psmatch2 treat c.age_p##c.age_p i.country i.educ chronic_p if wave==7,   ///
out(casp) radius common caliper(.01) 

***************************************************************************************
*Kernel
psmatch2 treat c.age_p##c.age_p i.country i.educ chronic_p if wave==7,   ///
out(casp1) kernel k(normal) bw(0.05) common caliper(.01) 

psmatch2 treat c.age_p##c.age_p i.country i.educ chronic_p if wave==7,  ///
out(casp) kernel k(normal) bw(0.05) common caliper(.01)